Build an equipment-request app around your company's rules.

Independent Finance approval above €1,000

When
 crud Equipment by=coordinator fields=name,category,active delete=none
 crud Request by=members fields=equipment,reason,amount when=row.requested_by==actor and row.status==requested delete=none
 # Review another teammate's request against the equipment catalogue.
 scenario approve(request:Request) by=reviewer
  require request.status==requested and request.requested_by!=actor
  require request.equipment.active
  do
   if request.policy==finance_threshold and request.amount!=null and request.amount.minor>100000
    set request {status=awaiting_finance,approved_by=actor,approved_at=now}
   else
    set request {status=approved,approved_by=actor,approved_at=now}
  examples request=pending
   as,request.amount,request.policy -> request.status
   first_reviewer,money(450,"EUR"),finance_threshold -> approved
   first_reviewer,money(1000,"EUR"),finance_threshold -> approved
   first_reviewer,money(1400,"EUR"),finance_threshold -> awaiting_finance
   first_reviewer,money(1400,"EUR"),original -> approved
   first_reviewer,null,original -> approved
   members,money(450,"EUR"),finance_threshold -> error(forbidden)
  examples request=pending
   as,request.requested_by,request.status -> request.status
   first_reviewer,first_reviewer,requested -> error(rule_failed)
   first_reviewer,claimant,approved -> error(rule_failed)
 # Finance must be a third person, even when one person has multiple roles.
 scenario approve_finance(request:Request) by=finance
  require request.status==awaiting_finance and request.policy==finance_threshold
  require request.requested_by!=actor and request.approved_by!=actor
  do set request {status=approved,finance_by=actor,finance_at=now}
  examples request=pending
   as,request.status,request.amount,request.approved_by -> request.status,request.finance_by
   finance_reviewer,awaiting_finance,money(1400,"EUR"),first_reviewer -> approved,finance_reviewer
   first_reviewer,awaiting_finance,money(1400,"EUR"),first_reviewer -> error(rule_failed)
   claimant,awaiting_finance,money(1400,"EUR"),first_reviewer -> error(rule_failed)
   finance_reviewer,approved,money(1400,"EUR"),first_reviewer -> error(rule_failed)
 # Record the physical asset when approved equipment reaches the requester.
 scenario deliver(request:Request,asset_tag:text) by=coordinator
  require request.status==approved and trim(asset_tag)!=""
  do set request {status=delivered,asset_tag=trim(asset_tag),delivered_at=now}
  examples request=pending
   as,request.status,asset_tag -> request.status,request.asset_tag
   coordinator,approved,"DESK-104" -> delivered,"DESK-104"
   coordinator,awaiting_finance,"DESK-104" -> error(rule_failed)
   coordinator,approved," " -> error(rule_failed)
   members,approved,"DESK-104" -> error(forbidden)
   coordinator,delivered,"DESK-104" -> error(rule_failed)